Отново Acer A1

Този път ситуацията е следната:
Трикратно по-бавно стартиране на OS (XP Home), деформирано възпроизвеждане на стартовата мелодия на Windows при log-ване. Забелязва се, че дисковите операции са забавени чувствително.
Оказа се, че по причини извеснти само на Microsoft диска е минал в режим на PIO вместо на по-бързия DMA режим. Едни хора, които трябва да черпя, са написали vbs, с който се reset-ва тази настройка в registry-то.

Цялата статия е тук

А ето го и скрипта. Просто красота:

' Visual Basic Script program to reset the DMA status of all ATA drives
' Copyright © 2006 Hans-Georg Michna
' Version 2007-04-04
' Works in Windows XP, probably also in Windows 2000 and NT.
' Does no harm if Windows version is incompatible.

If MsgBox("This program will now reset the DMA status of all ATA drives with Windows drivers." _
& vbNewline & "Windows will redetect the status after the next reboot, therefore this procedure" _
& vbNewline & "should be harmless.", _
vbOkCancel, "Program start message") _
= vbOk Then

RegPath = "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Class\{4D36E96A-E325-11CE-BFC1-08002BE10318}\"
ValueName1Master = "MasterIdDataChecksum"
ValueName1Slave = "SlaveIdDataChecksum"
ValueName2Master = "UserMasterDeviceTimingModeAllowed"
ValueName2Slave = "UserSlaveDeviceTimingModeAllowed"
ValueName3 = "ResetErrorCountersOnSuccess"
MessageText = "The following ATA channels have been reset:"
MessageTextLen0 = Len(MessageText)
ConsecutiveMisses = 0
Set WshShell = WScript.CreateObject("WScript.Shell")

For i = 0 to 999
RegSubPath = Right("000" & i, 4) & "\"

' Master

Err.Clear
On Error Resume Next
WshShell.RegRead RegPath & RegSubPath & ValueName1Master
errMaster = Err.Number
On Error Goto 0
If errMaster = 0 Then
On Error Resume Next
WshShell.RegDelete RegPath & RegSubPath & ValueName1Master
WshShell.RegDelete RegPath & RegSubPath & ValueName2Master
On Error Goto 0
MessageText = MessageText & vbNewLine & "Master"
End If

' Slave

Err.Clear
On Error Resume Next
WshShell.RegRead RegPath & RegSubPath & ValueName1Slave
errSlave = Err.Number
On Error Goto 0
If errSlave = 0 Then
On Error Resume Next
WshShell.RegDelete RegPath & RegSubPath & ValueName1Slave
WshShell.RegDelete RegPath & RegSubPath & ValueName2Slave
On Error Goto 0
If errMaster = 0 Then
MessageText = MessageText & " and "
Else
MessageText = MessageText & vbNewLine
End If
MessageText = MessageText & "Slave"
End If

If errMaster = 0 Or errSlave = 0 Then
On Error Resume Next
WshShell.RegWrite RegPath & RegSubPath & ValueName3, 1, "REG_DWORD"
On Error Goto 0
ChannelName = "unnamed channel " & Left(RegSubPath, 4)
On Error Resume Next
ChannelName = WshShell.RegRead(RegPath & RegSubPath & "DriverDesc")
On Error Goto 0
MessageText = MessageText & " of " & ChannelName & ";"
ConsecutiveMisses = 0
Else
ConsecutiveMisses = ConsecutiveMisses + 1
If ConsecutiveMisses >= 32 Then Exit For ' Don't search unnecessarily long.
End If
Next ' i

If Len(MessageText) <= MessageTextLen0 Then
MessageText = "No resettable ATA channels with Windows drivers found. Nothing changed."
Else
MessageText = MessageText & vbNewline _
& "Please reboot now to reset and redetect the DMA status."
End If

MsgBox MessageText, vbOkOnly, "Program finished normally"

End If ' MsgBox(...) = vbOk

' End of Visual Basic Script program

Acer Aspire One Black Screen

Aspire One BIOS Recovеry
19.09.2009

Нетбука се държи така сякаш му е изгоряло видеото - черен екран и на неговия си монитор и на външен, ако се стите да закачите такъв. Не свети нито един индикатор освен този на захранването. След малко четене в нета се оказва, че на тези модели по непонятни причини на 6-я месец от ползването им се омазва жестоко BIOS-a. Не ме питайте защо.

За възстановяване/обновяване на BIOS-а:

1. USB stick – форматиран на FAT
2. Последна или поне текущата версия на BIOS – за конкретния модел

Аз (AA1 ZG5) ги свалих от тук
(На 22.04.2014 имаме същия проблем. Файловете за BIOS-a ги свалих от тук)
Слагаме FLASHIT.EXE, 3309.bat и BIOS файла в root директорията на флашката. Копираме BIOS файла zg*.fd като ZG5IA32.FD
Изключваме АА1, и батерията и адаптера да са свързани с компютъра.
Натискаме тайния клавиш Fn+Esc, задържаме и натискаме Power бутона. След малко пускаме Fn+Esc клавишите и зеленият индикатор на Power бутони трябва да започне да мига. Демек стартирало се е флашването на BIOS. Тук стискаме палци и си кръстосваме краката. Не прекъсваме процеса(!!!), след известно време Power бутона ще спре да мига и АА1 ще стартира/ reboot. При мен отне 30 секунди слава богу и ооо чудо нещото тръгна.

Айде честито!