Отново Acer A1

Този път ситуацията е следната:
Трикратно по-бавно стартиране на OS (XP Home), деформирано възпроизвеждане на стартовата мелодия на Windows при log-ване. Забелязва се, че дисковите операции са забавени чувствително.
Оказа се, че по причини извеснти само на Microsoft диска е минал в режим на PIO вместо на по-бързия DMA режим. Едни хора, които трябва да черпя, са написали vbs, с който се reset-ва тази настройка в registry-то.

Цялата статия е тук

А ето го и скрипта. Просто красота:

' Visual Basic Script program to reset the DMA status of all ATA drives
' Copyright © 2006 Hans-Georg Michna
' Version 2007-04-04
' Works in Windows XP, probably also in Windows 2000 and NT.
' Does no harm if Windows version is incompatible.

If MsgBox("This program will now reset the DMA status of all ATA drives with Windows drivers." _
& vbNewline & "Windows will redetect the status after the next reboot, therefore this procedure" _
& vbNewline & "should be harmless.", _
vbOkCancel, "Program start message") _
= vbOk Then

RegPath = "HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Class\{4D36E96A-E325-11CE-BFC1-08002BE10318}\"
ValueName1Master = "MasterIdDataChecksum"
ValueName1Slave = "SlaveIdDataChecksum"
ValueName2Master = "UserMasterDeviceTimingModeAllowed"
ValueName2Slave = "UserSlaveDeviceTimingModeAllowed"
ValueName3 = "ResetErrorCountersOnSuccess"
MessageText = "The following ATA channels have been reset:"
MessageTextLen0 = Len(MessageText)
ConsecutiveMisses = 0
Set WshShell = WScript.CreateObject("WScript.Shell")

For i = 0 to 999
RegSubPath = Right("000" & i, 4) & "\"

' Master

Err.Clear
On Error Resume Next
WshShell.RegRead RegPath & RegSubPath & ValueName1Master
errMaster = Err.Number
On Error Goto 0
If errMaster = 0 Then
On Error Resume Next
WshShell.RegDelete RegPath & RegSubPath & ValueName1Master
WshShell.RegDelete RegPath & RegSubPath & ValueName2Master
On Error Goto 0
MessageText = MessageText & vbNewLine & "Master"
End If

' Slave

Err.Clear
On Error Resume Next
WshShell.RegRead RegPath & RegSubPath & ValueName1Slave
errSlave = Err.Number
On Error Goto 0
If errSlave = 0 Then
On Error Resume Next
WshShell.RegDelete RegPath & RegSubPath & ValueName1Slave
WshShell.RegDelete RegPath & RegSubPath & ValueName2Slave
On Error Goto 0
If errMaster = 0 Then
MessageText = MessageText & " and "
Else
MessageText = MessageText & vbNewLine
End If
MessageText = MessageText & "Slave"
End If

If errMaster = 0 Or errSlave = 0 Then
On Error Resume Next
WshShell.RegWrite RegPath & RegSubPath & ValueName3, 1, "REG_DWORD"
On Error Goto 0
ChannelName = "unnamed channel " & Left(RegSubPath, 4)
On Error Resume Next
ChannelName = WshShell.RegRead(RegPath & RegSubPath & "DriverDesc")
On Error Goto 0
MessageText = MessageText & " of " & ChannelName & ";"
ConsecutiveMisses = 0
Else
ConsecutiveMisses = ConsecutiveMisses + 1
If ConsecutiveMisses >= 32 Then Exit For ' Don't search unnecessarily long.
End If
Next ' i

If Len(MessageText) <= MessageTextLen0 Then
MessageText = "No resettable ATA channels with Windows drivers found. Nothing changed."
Else
MessageText = MessageText & vbNewline _
& "Please reboot now to reset and redetect the DMA status."
End If

MsgBox MessageText, vbOkOnly, "Program finished normally"

End If ' MsgBox(...) = vbOk

' End of Visual Basic Script program

Сталинчета ...

18.11.2009

«... Сталинчето от мое време: това беше мъничко, енергично, амбициозно, злобно самотно същество, за което командуването, малтретирането, заплашването и тероризирането на други човешки същества бе психопатологична необходимост. Сталинчето искаше да бъде забелязано, че съществува, искаше светът да го види, да го чуе и някак да му се поклони. И тъй като обикновено му липсваха способности да бъде добър земеделец, шивач, стругар, артист, тъй като му липсваха способности да бъде обикновен трудещ се човек, у него се бяха напластили завист и омраза към всички, които притежаваха тези способности, към добрия, човечен, хармоничен свят на толерантността и любовта, в който нямаше място за бесове. За нашите български сталинчета революцията не е била никога нищо друго освен удобен претекст за пускане в действие на струята от низши страсти и инстинкти, на дяволско удовлетворение, на болезнен комплекс за малоценност. Бруталното физическо смазване на чуждата воля се превръщаше в триумф на собствено превъзходство. Партията, социализмът и комунизмът бяха оправданието. И всред тази глутница ние трябваше да живеем и да вярваме в човека.”
Георги Марков „Задочни репортажи за България”

Те съществуват и сега – онези ниско интелигентни, мързеливи, некадърни, но с огромно самочувствие подхранвано от близки, роднини и приятели и с още по огромни комплекси млади хора. Ако енергията на тяхната омраза се впрегне по някакъв начин, не ни трябват нито АЕЦ, нито ТЕЦ, нито ВЕЦ. Но лошото е, че те се хранят с хора, а от този ресурс добивите са ниски (и все по-ниски стават). И колкото по пълноценен е изконсумирания човек, толкова повече енергия произвеждат гадовете.
За щастие онези времена, за които говори Г. Марков са отминали (надявам се). Сега тези синковци освен престъпници, други не могат да станат (надявам се), а с престъпниците знаем горе-долу как да се оправяме (надявам се).
И новия ЗЕС не е стъпка назад (надявам се).